# Stream macro

**URL:** <https://forum.crystal-lang.org/t/stream-macro/7986>\
**Category:** Help & Support\
**Created:** [April 22, 2025, 5:38pm UTC](https://forum.crystal-lang.org/t/stream-macro/7986 "2025-04-22T17:38:36Z")\
**Posts on this page:** 15\
**Page:** 1

<div class="post-metadata">

**Author:** ![siery](https://yyz2.discourse-cdn.com/flex036/user_avatar/forum.crystal-lang.org/siery/32/1875_2.png) [@siery](https://forum.crystal-lang.org/u/siery)\
**Post date:** [April 22, 2025, 5:38pm UTC](https://forum.crystal-lang.org/t/stream-macro/7986/1 "2025-04-22T17:38:36Z")

</div>

I been trying to make using streams simpler with this little macro:

```auto
macro stream(&block)
  String.build do |io|
    io << {{block}}
  end
end

macro puts_stream(&block)
  print stream do
    {{block}} << '\n'
  end
end

```

However, when I try to call it:

```auto
puts_stream {
  "Hello, world!"
}

```

I get error:

```auto
expecting identifier 'end', not 'do'

```

So macros does not accept blocks? Or am I doing something wrong?

It’s probably a dumb question, I been not using Crystal for a long time.

---

<div class="post-metadata">

**Author:** ![Blacksmoke16](https://yyz2.discourse-cdn.com/flex036/user_avatar/forum.crystal-lang.org/blacksmoke16/32/1241_2.png) [@Blacksmoke16](https://forum.crystal-lang.org/u/Blacksmoke16)\
**Post date:** [April 22, 2025, 6:04pm UTC](https://forum.crystal-lang.org/t/stream-macro/7986/2 "2025-04-22T18:04:54Z")

</div>

Not entirely sure I follow what the use case here is, but does this even need to be a macro? Probably would be a bit easier to implement as a normal method.

Either way I think what’s going on here is it’s expanding to something like:

```crystal
print stream do
  do
    "Hello, world!"
  end << '\n'
end

```

which is of course invalid syntax.

---

<div class="post-metadata">

**Author:** ![siery](https://yyz2.discourse-cdn.com/flex036/user_avatar/forum.crystal-lang.org/siery/32/1875_2.png) [@siery](https://forum.crystal-lang.org/u/siery)\
**Post date:** [April 22, 2025, 6:12pm UTC](https://forum.crystal-lang.org/t/stream-macro/7986/3 "2025-04-22T18:12:24Z")

</div>

My idea was to allow users to append to stream with `<<`. I was hoping to use it in other macros like:

```auto
macro colorize(s, color)
  stream do
    "\e[0;" << {{color}}.to_s << ";49m" << {{s}} << "\e[0m"
  end
end

macro red(s)
  colorize({{s}}, 31)
end

macro green(s)
  colorize({{s}}, 32)
end

macro yellow(s)
  colorize({{s}}, 33)
end

macro blue(s)
  colorize({{s}}, 34)
end

macro magenta(s)
  colorize({{s}}, 35)
end

```

---

<div class="post-metadata">

**Author:** ![Blacksmoke16](https://yyz2.discourse-cdn.com/flex036/user_avatar/forum.crystal-lang.org/blacksmoke16/32/1241_2.png) [@Blacksmoke16](https://forum.crystal-lang.org/u/Blacksmoke16)\
**Post date:** [April 22, 2025, 6:17pm UTC](https://forum.crystal-lang.org/t/stream-macro/7986/4 "2025-04-22T18:17:08Z")

</div>

> [@siery](#):
>
> My idea was to allow users to append to stream with `<<`.

You already can do this via [`IO#<<`](https://crystal-lang.org/api/IO.html#%3C%3C(obj):self-instance-method). It returns `self` so can chain it on a single line.

Also maybe could just use [Colorize - Crystal 1.16.1](https://crystal-lang.org/api/Colorize.html) instead of implementing your own API?

---

<div class="post-metadata">

**Author:** ![siery](https://yyz2.discourse-cdn.com/flex036/user_avatar/forum.crystal-lang.org/siery/32/1875_2.png) [@siery](https://forum.crystal-lang.org/u/siery)\
**Post date:** [April 22, 2025, 6:57pm UTC](https://forum.crystal-lang.org/t/stream-macro/7986/5 "2025-04-22T18:57:18Z")

</div>

Thanks, I get that now. I don’t get though why am I still getting `unexpected token: "<<"` here:

```auto
macro stream(*args)
  io = IO::Memory.new
  (io
  {% for arg in args %}
    << {{arg}}
  {% end %})
  io.to_s
end

```

It should expand to something like:

```auto
 > 1 | io = IO::Memory.new
 > 2 | (io
 > 3 | << "test"
 > 4 | )
 > 5 | io.to_s

```

---

<div class="post-metadata">

**Author:** ![siery](https://yyz2.discourse-cdn.com/flex036/user_avatar/forum.crystal-lang.org/siery/32/1875_2.png) [@siery](https://forum.crystal-lang.org/u/siery)\
**Post date:** [April 22, 2025, 6:59pm UTC](https://forum.crystal-lang.org/t/stream-macro/7986/6 "2025-04-22T18:59:16Z")

</div>

Okay, never mind. It works on a single line:

```auto
macro stream(*args)
  io = IO::Memory.new
  (io {% for arg in args %} << {{arg}} {% end %})
  io.to_s
end

```

---

<div class="post-metadata">

**Author:** ![Blacksmoke16](https://yyz2.discourse-cdn.com/flex036/user_avatar/forum.crystal-lang.org/blacksmoke16/32/1241_2.png) [@Blacksmoke16](https://forum.crystal-lang.org/u/Blacksmoke16)\
**Post date:** [April 22, 2025, 7:01pm UTC](https://forum.crystal-lang.org/t/stream-macro/7986/7 "2025-04-22T19:01:05Z")

</div>

```crystal
def stream(*args : String) : String
  args.join
end

```

Should do the same thing as you have, but a bit simpler.

---

<div class="post-metadata">

**Author:** ![siery](https://yyz2.discourse-cdn.com/flex036/user_avatar/forum.crystal-lang.org/siery/32/1875_2.png) [@siery](https://forum.crystal-lang.org/u/siery)\
**Post date:** [April 22, 2025, 7:02pm UTC](https://forum.crystal-lang.org/t/stream-macro/7986/8 "2025-04-22T19:02:41Z")

</div>

Yes, but it uses `String` for interpolation. I meant to use stream to make it more efficient

---

<div class="post-metadata">

**Author:** ![Blacksmoke16](https://yyz2.discourse-cdn.com/flex036/user_avatar/forum.crystal-lang.org/blacksmoke16/32/1241_2.png) [@Blacksmoke16](https://forum.crystal-lang.org/u/Blacksmoke16)\
**Post date:** [April 22, 2025, 7:04pm UTC](https://forum.crystal-lang.org/t/stream-macro/7986/9 "2025-04-22T19:04:26Z")

</div>

Mmk, I’ll be curious to see the final product then. Because `IO::Memory` is also just in memory so not really getting any benefit there. [`Indexable#join`](https://crystal-lang.org/api/master/Indexable.html#join%28separator%3AString%7CChar%7CNumber%3D%22%22%29%3AString-instance-method) might even be _more_ efficient since it can make some assumptions about the data. Which is called out in the API docs:

> Optimized version of Enumerable#join that performs better when all of the elements in this indexable are strings: the total string bytesize to return can be computed before creating the final string, which performs better because there’s no need to do reallocations.

---

<div class="post-metadata">

**Author:** ![siery](https://yyz2.discourse-cdn.com/flex036/user_avatar/forum.crystal-lang.org/siery/32/1875_2.png) [@siery](https://forum.crystal-lang.org/u/siery)\
**Post date:** [April 22, 2025, 7:15pm UTC](https://forum.crystal-lang.org/t/stream-macro/7986/10 "2025-04-22T19:15:54Z")

</div>

I just assumed streams will be faster. So, this is also pointless 🫠?

```auto
macro stream(*args)
  String.build do |io|
    io {% for arg in args %} << {{arg}} {% end %}
  end
end

```

---

<div class="post-metadata">

**Author:** ![Blacksmoke16](https://yyz2.discourse-cdn.com/flex036/user_avatar/forum.crystal-lang.org/blacksmoke16/32/1241_2.png) [@Blacksmoke16](https://forum.crystal-lang.org/u/Blacksmoke16)\
**Post date:** [April 22, 2025, 7:19pm UTC](https://forum.crystal-lang.org/t/stream-macro/7986/11 "2025-04-22T19:19:57Z")

</div>

> [@siery](#):
>
> I just assumed streams will be faster

If this benchmark is correct:

```crystal
require "benchmark"

def def_stream(*args : String) : String
  args.join
end

macro macro_stream(*args)
  String.build do |io|
    io {% for arg in args %} << {{arg}} {% end %}
  end
end

Benchmark.ips do |x|
  x.report "def_stream" do
    def_stream(
      "Lorem ipsum dolor sit amet, consectetur adipiscing elit.",
      "Phasellus nec sem id quam placerat viverra vel non urna.",
      "In quis odio et erat feugiat fermentum vitae id nibh.",
      "Sed sed erat et sem aliquet placerat posuere egestas est.",
      "Aenean at lectus rutrum, condimentum sem quis, cursus arcu.",
      "Nullam ac tortor pretium, scelerisque ex vel, ullamcorper felis.",
      "Quisque accumsan urna sed feugiat dignissim.",
      "Sed mattis lacus vitae felis tempus facilisis non a ipsum.",
      "Pellentesque suscipit tortor non quam mollis feugiat.",
      "Ut cursus lacus ac tellus gravida, eget bibendum mi hendrerit.",
      "Quisque eu est et libero volutpat dapibus.",
      "Aliquam lobortis urna viverra justo congue molestie.",
      "Maecenas efficitur nibh quis diam elementum, nec varius justo pulvinar.",
      "Donec et est bibendum, vehicula augue ut, tempor mi.",
      "Phasellus eget risus tincidunt, egestas ex in, tristique neque.",
      "Donec consectetur tellus quis consequat ullamcorper.",
      "Nullam sollicitudin augue nec lacus porta consequat.",
      "Fusce aliquam libero in orci semper, nec viverra enim elementum.",
      "Praesent mollis turpis vitae ex suscipit fringilla.",
      "Sed luctus tortor et odio lacinia, et feugiat augue vestibulum.",
    )
  end

  x.report "def_stream" do
    macro_stream(
      "Lorem ipsum dolor sit amet, consectetur adipiscing elit.",
      "Phasellus nec sem id quam placerat viverra vel non urna.",
      "In quis odio et erat feugiat fermentum vitae id nibh.",
      "Sed sed erat et sem aliquet placerat posuere egestas est.",
      "Aenean at lectus rutrum, condimentum sem quis, cursus arcu.",
      "Nullam ac tortor pretium, scelerisque ex vel, ullamcorper felis.",
      "Quisque accumsan urna sed feugiat dignissim.",
      "Sed mattis lacus vitae felis tempus facilisis non a ipsum.",
      "Pellentesque suscipit tortor non quam mollis feugiat.",
      "Ut cursus lacus ac tellus gravida, eget bibendum mi hendrerit.",
      "Quisque eu est et libero volutpat dapibus.",
      "Aliquam lobortis urna viverra justo congue molestie.",
      "Maecenas efficitur nibh quis diam elementum, nec varius justo pulvinar.",
      "Donec et est bibendum, vehicula augue ut, tempor mi.",
      "Phasellus eget risus tincidunt, egestas ex in, tristique neque.",
      "Donec consectetur tellus quis consequat ullamcorper.",
      "Nullam sollicitudin augue nec lacus porta consequat.",
      "Fusce aliquam libero in orci semper, nec viverra enim elementum.",
      "Praesent mollis turpis vitae ex suscipit fringilla.",
      "Sed luctus tortor et odio lacinia, et feugiat augue vestibulum.",
    )
  end
end

```

Then yes, the macro version is 3x slower than the method version:

```sh
$ crystal run --release test.cr
  def_stream 11.70M ( 85.46ns) (± 2.61%) 1.31kB/op fastest
macro_stream 3.56M (281.24ns) (± 1.44%) 5.78kB/op 3.29× slower

```

---

<div class="post-metadata">

**Author:** ![siery](https://yyz2.discourse-cdn.com/flex036/user_avatar/forum.crystal-lang.org/siery/32/1875_2.png) [@siery](https://forum.crystal-lang.org/u/siery)\
**Post date:** [April 22, 2025, 8:12pm UTC](https://forum.crystal-lang.org/t/stream-macro/7986/12 "2025-04-22T20:12:39Z")

</div>

Thanks for sanity check. Look at this though:

```crystal
require "benchmark"

def def_stream(*args : String) : String
  args.join
end

macro macro_stream(*args)
  {% result = "" %}
  {% for arg in args %}
    {% result += arg %}
  {% end %}
  {{ result }}
end

Benchmark.ips do |x|
  x.report "def_stream" do
    def_stream(
      "Lorem ipsum dolor sit amet, consectetur adipiscing elit.",
      "Phasellus nec sem id quam placerat viverra vel non urna.",
      "In quis odio et erat feugiat fermentum vitae id nibh.",
      "Sed sed erat et sem aliquet placerat posuere egestas est.",
      "Aenean at lectus rutrum, condimentum sem quis, cursus arcu.",
      "Nullam ac tortor pretium, scelerisque ex vel, ullamcorper felis.",
      "Quisque accumsan urna sed feugiat dignissim.",
      "Sed mattis lacus vitae felis tempus facilisis non a ipsum.",
      "Pellentesque suscipit tortor non quam mollis feugiat.",
      "Ut cursus lacus ac tellus gravida, eget bibendum mi hendrerit.",
      "Quisque eu est et libero volutpat dapibus.",
      "Aliquam lobortis urna viverra justo congue molestie.",
      "Maecenas efficitur nibh quis diam elementum, nec varius justo pulvinar.",
      "Donec et est bibendum, vehicula augue ut, tempor mi.",
      "Phasellus eget risus tincidunt, egestas ex in, tristique neque.",
      "Donec consectetur tellus quis consequat ullamcorper.",
      "Nullam sollicitudin augue nec lacus porta consequat.",
      "Fusce aliquam libero in orci semper, nec viverra enim elementum.",
      "Praesent mollis turpis vitae ex suscipit fringilla.",
      "Sed luctus tortor et odio lacinia, et feugiat augue vestibulum.",
    )
  end

  x.report "macro_stream" do
    macro_stream(
      "Lorem ipsum dolor sit amet, consectetur adipiscing elit.",
      "Phasellus nec sem id quam placerat viverra vel non urna.",
      "In quis odio et erat feugiat fermentum vitae id nibh.",
      "Sed sed erat et sem aliquet placerat posuere egestas est.",
      "Aenean at lectus rutrum, condimentum sem quis, cursus arcu.",
      "Nullam ac tortor pretium, scelerisque ex vel, ullamcorper felis.",
      "Quisque accumsan urna sed feugiat dignissim.",
      "Sed mattis lacus vitae felis tempus facilisis non a ipsum.",
      "Pellentesque suscipit tortor non quam mollis feugiat.",
      "Ut cursus lacus ac tellus gravida, eget bibendum mi hendrerit.",
      "Quisque eu est et libero volutpat dapibus.",
      "Aliquam lobortis urna viverra justo congue molestie.",
      "Maecenas efficitur nibh quis diam elementum, nec varius justo pulvinar.",
      "Donec et est bibendum, vehicula augue ut, tempor mi.",
      "Phasellus eget risus tincidunt, egestas ex in, tristique neque.",
      "Donec consectetur tellus quis consequat ullamcorper.",
      "Nullam sollicitudin augue nec lacus porta consequat.",
      "Fusce aliquam libero in orci semper, nec viverra enim elementum.",
      "Praesent mollis turpis vitae ex suscipit fringilla.",
      "Sed luctus tortor et odio lacinia, et feugiat augue vestibulum.",
    )
  end
end 

```

output:

```auto
def_stream 2.98M (335.77ns) (± 6.97%) 1.31kB/op 252.88× slower
macro_stream 753.13M ( 1.33ns) (± 7.07%) 0.0B/op fastest

```

---

<div class="post-metadata">

**Author:** ![Blacksmoke16](https://yyz2.discourse-cdn.com/flex036/user_avatar/forum.crystal-lang.org/blacksmoke16/32/1241_2.png) [@Blacksmoke16](https://forum.crystal-lang.org/u/Blacksmoke16)\
**Post date:** [April 22, 2025, 8:30pm UTC](https://forum.crystal-lang.org/t/stream-macro/7986/13 "2025-04-22T20:30:13Z")

</div>

Yes this makes sense as with this version you’re essentially building the final string at compile time and including it in the program. So at runtime nothing has to be done as it would be the same as hard coding the string. `{{args.join ""}}` would have the same result, but a bit more readable.

However one thing to keep in mind is as it stands this macro version can only handle cases where all the strings are provided as hard coded strings. I.e. you couldn’t pass it local vars to the macro version. For one because it cannot handle `Var` input nodes, and if you fix that (e.g. using `args.join ""`), because it cannot know the runtime value of those variables.

```crystal
def def_stream(*args : String) : String
  args.join
end

macro macro_stream(*args)
  {{ args.join "" }}
end

foo = "i am a string"

puts macro_stream foo, foo, foo # => foofoofoo
puts def_stream foo, foo, foo # => i am a stringi am a stringi am a string

```

---

<div class="post-metadata">

**Author:** ![siery](https://yyz2.discourse-cdn.com/flex036/user_avatar/forum.crystal-lang.org/siery/32/1875_2.png) [@siery](https://forum.crystal-lang.org/u/siery)\
**Post date:** [April 22, 2025, 8:33pm UTC](https://forum.crystal-lang.org/t/stream-macro/7986/14 "2025-04-22T20:33:43Z")

</div>

Yes, this is what I needed. Don’t worry, I know it’s compile time and not really type safe.

---

<div class="post-metadata">

**Author:** ![bcardiff](https://yyz2.discourse-cdn.com/flex036/user_avatar/forum.crystal-lang.org/bcardiff/32/3_2.png) [@bcardiff](https://forum.crystal-lang.org/u/bcardiff)\
**Post date:** [April 22, 2025, 8:45pm UTC](https://forum.crystal-lang.org/t/stream-macro/7986/15 "2025-04-22T20:45:46Z")

</div>

Not sure if related to what you are trying to do, but check how Log.define\_formatter works.

Is a macro that receives a string literal with interpolation. The interpolated values becomes into scope thanks to a the base class.

In the end you use regular string interpolation syntax but that string is never built.
